summaryrefslogtreecommitdiff
path: root/test/pleroma/web/mastodon_api/controllers/filter_controller_test.exs
blob: 4f71b40d1554a29c010efd5f9ee0df927abc1aa8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
# Pleroma: A lightweight social networking server
# Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
# SPDX-License-Identifier: AGPL-3.0-only

defmodule Pleroma.Web.MastodonAPI.FilterControllerTest do
  use Pleroma.Web.ConnCase, async: true
  use Oban.Testing, repo: Pleroma.Repo

  import Pleroma.Factory

  alias Pleroma.Filter
  alias Pleroma.Repo
  alias Pleroma.Workers.PurgeExpiredFilter

  test "non authenticated creation request", %{conn: conn} do
    response =
      conn
      |> put_req_header("content-type", "application/json")
      |> post("/api/v1/filters", %{"phrase" => "knights", context: ["home"]})
      |> json_response(403)

    assert response["error"] == "Invalid credentials."
  end

  describe "creating" do
    setup do: oauth_access(["write:filters"])

    test "a common filter", %{conn: conn, user: user} do
      params = %{
        phrase: "knights",
        context: ["home"],
        irreversible: true
      }

      response =
        conn
        |> put_req_header("content-type", "application/json")
        |> post("/api/v1/filters", params)
        |> json_response_and_validate_schema(200)

      assert response["phrase"] == params.phrase
      assert response["context"] == params.context
      assert response["irreversible"] == true
      assert response["id"] != nil
      assert response["id"] != ""
      assert response["expires_at"] == nil

      filter = Filter.get(response["id"], user)
      assert filter.hide == true
    end

    @tag :erratic
    test "a filter with expires_in", %{conn: conn, user: user} do
      in_seconds = 600

      response =
        conn
        |> put_req_header("content-type", "application/json")
        |> post("/api/v1/filters", %{
          "phrase" => "knights",
          context: ["home"],
          expires_in: in_seconds
        })
        |> json_response_and_validate_schema(200)

      assert response["irreversible"] == false

      expires_at =
        NaiveDateTime.utc_now()
        |> NaiveDateTime.add(in_seconds)
        |> Pleroma.Web.CommonAPI.Utils.to_masto_date()

      assert response["expires_at"] == expires_at

      filter = Filter.get(response["id"], user)

      id = filter.id

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: filter.id}
      )

      assert {:ok, %{id: ^id}} =
               perform_job(PurgeExpiredFilter, %{
                 filter_id: filter.id
               })

      assert Repo.aggregate(Filter, :count, :id) == 0
    end
  end

  test "fetching a list of filters" do
    %{user: user, conn: conn} = oauth_access(["read:filters"])

    %{filter_id: id1} = insert(:filter, user: user)
    %{filter_id: id2} = insert(:filter, user: user)

    id1 = to_string(id1)
    id2 = to_string(id2)

    assert [%{"id" => ^id2}, %{"id" => ^id1}] =
             conn
             |> get("/api/v1/filters")
             |> json_response_and_validate_schema(200)
  end

  test "fetching a list of filters without token", %{conn: conn} do
    insert(:filter)

    response =
      conn
      |> get("/api/v1/filters")
      |> json_response(403)

    assert response["error"] == "Invalid credentials."
  end

  test "get a filter" do
    %{user: user, conn: conn} = oauth_access(["read:filters"])

    # check whole_word false
    filter = insert(:filter, user: user, whole_word: false)

    resp1 =
      conn |> get("/api/v1/filters/#{filter.filter_id}") |> json_response_and_validate_schema(200)

    assert resp1["whole_word"] == false

    # check whole_word true
    filter = insert(:filter, user: user, whole_word: true)

    resp2 =
      conn |> get("/api/v1/filters/#{filter.filter_id}") |> json_response_and_validate_schema(200)

    assert resp2["whole_word"] == true
  end

  test "get a filter not_found error" do
    filter = insert(:filter)
    %{conn: conn} = oauth_access(["read:filters"])

    response =
      conn |> get("/api/v1/filters/#{filter.filter_id}") |> json_response_and_validate_schema(404)

    assert response["error"] == "Record not found"
  end

  describe "updating a filter" do
    setup do: oauth_access(["write:filters"])

    test "common" do
      %{conn: conn, user: user} = oauth_access(["write:filters"])

      filter =
        insert(:filter,
          user: user,
          hide: true,
          whole_word: true
        )

      params = %{
        phrase: "nii",
        context: ["public"],
        irreversible: false
      }

      response =
        conn
        |> put_req_header("content-type", "application/json")
        |> put("/api/v1/filters/#{filter.filter_id}", params)
        |> json_response_and_validate_schema(200)

      assert response["phrase"] == params.phrase
      assert response["context"] == params.context
      assert response["irreversible"] == false
      assert response["whole_word"] == true
    end

    test "with adding expires_at", %{conn: conn, user: user} do
      filter = insert(:filter, user: user)
      in_seconds = 600

      response =
        conn
        |> put_req_header("content-type", "application/json")
        |> put("/api/v1/filters/#{filter.filter_id}", %{
          phrase: "nii",
          context: ["public"],
          expires_in: in_seconds,
          irreversible: true
        })
        |> json_response_and_validate_schema(200)

      assert response["irreversible"] == true

      assert response["expires_at"] ==
               NaiveDateTime.utc_now()
               |> NaiveDateTime.add(in_seconds)
               |> Pleroma.Web.CommonAPI.Utils.to_masto_date()

      filter = Filter.get(response["id"], user)

      id = filter.id

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: id}
      )

      assert {:ok, %{id: ^id}} =
               perform_job(PurgeExpiredFilter, %{
                 filter_id: id
               })

      assert Repo.aggregate(Filter, :count, :id) == 0
    end

    test "with removing expires_at", %{conn: conn, user: user} do
      response =
        conn
        |> put_req_header("content-type", "application/json")
        |> post("/api/v1/filters", %{
          phrase: "cofe",
          context: ["home"],
          expires_in: 600
        })
        |> json_response_and_validate_schema(200)

      filter = Filter.get(response["id"], user)

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: filter.id}
      )

      response =
        conn
        |> put_req_header("content-type", "application/json")
        |> put("/api/v1/filters/#{filter.filter_id}", %{
          phrase: "nii",
          context: ["public"],
          expires_in: nil,
          whole_word: true
        })
        |> json_response_and_validate_schema(200)

      refute_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: filter.id}
      )

      assert response["irreversible"] == false
      assert response["whole_word"] == true
      assert response["expires_at"] == nil
    end

    test "expires_at is the same in create and update so job is in db", %{conn: conn, user: user} do
      resp1 =
        conn
        |> put_req_header("content-type", "application/json")
        |> post("/api/v1/filters", %{
          phrase: "cofe",
          context: ["home"],
          expires_in: 600
        })
        |> json_response_and_validate_schema(200)

      filter = Filter.get(resp1["id"], user)

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: filter.id}
      )

      job = PurgeExpiredFilter.get_expiration(filter.id)

      resp2 =
        conn
        |> put_req_header("content-type", "application/json")
        |> put("/api/v1/filters/#{filter.filter_id}", %{
          phrase: "nii",
          context: ["public"]
        })
        |> json_response_and_validate_schema(200)

      updated_filter = Filter.get(resp2["id"], user)

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: updated_filter.id}
      )

      after_update = PurgeExpiredFilter.get_expiration(updated_filter.id)

      assert resp1["expires_at"] == resp2["expires_at"]

      assert job.scheduled_at == after_update.scheduled_at
    end

    test "updating expires_at updates oban job too", %{conn: conn, user: user} do
      resp1 =
        conn
        |> put_req_header("content-type", "application/json")
        |> post("/api/v1/filters", %{
          phrase: "cofe",
          context: ["home"],
          expires_in: 600
        })
        |> json_response_and_validate_schema(200)

      filter = Filter.get(resp1["id"], user)

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: filter.id}
      )

      job = PurgeExpiredFilter.get_expiration(filter.id)

      resp2 =
        conn
        |> put_req_header("content-type", "application/json")
        |> put("/api/v1/filters/#{filter.filter_id}", %{
          phrase: "nii",
          context: ["public"],
          expires_in: 300
        })
        |> json_response_and_validate_schema(200)

      updated_filter = Filter.get(resp2["id"], user)

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: updated_filter.id}
      )

      after_update = PurgeExpiredFilter.get_expiration(updated_filter.id)

      refute resp1["expires_at"] == resp2["expires_at"]

      refute job.scheduled_at == after_update.scheduled_at
    end
  end

  test "update filter without token", %{conn: conn} do
    filter = insert(:filter)

    response =
      conn
      |> put_req_header("content-type", "application/json")
      |> put("/api/v1/filters/#{filter.filter_id}", %{
        phrase: "nii",
        context: ["public"]
      })
      |> json_response(403)

    assert response["error"] == "Invalid credentials."
  end

  describe "delete a filter" do
    setup do: oauth_access(["write:filters"])

    test "common", %{conn: conn, user: user} do
      filter = insert(:filter, user: user)

      assert conn
             |> delete("/api/v1/filters/#{filter.filter_id}")
             |> json_response_and_validate_schema(200) == %{}

      assert Repo.all(Filter) == []
    end

    test "with expires_at", %{conn: conn, user: user} do
      response =
        conn
        |> put_req_header("content-type", "application/json")
        |> post("/api/v1/filters", %{
          phrase: "cofe",
          context: ["home"],
          expires_in: 600
        })
        |> json_response_and_validate_schema(200)

      filter = Filter.get(response["id"], user)

      assert_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: filter.id}
      )

      assert conn
             |> delete("/api/v1/filters/#{filter.filter_id}")
             |> json_response_and_validate_schema(200) == %{}

      refute_enqueued(
        worker: PurgeExpiredFilter,
        args: %{filter_id: filter.id}
      )

      assert Repo.all(Filter) == []
      assert Repo.all(Oban.Job) == []
    end
  end

  test "delete a filter without token", %{conn: conn} do
    filter = insert(:filter)

    response =
      conn
      |> delete("/api/v1/filters/#{filter.filter_id}")
      |> json_response(403)

    assert response["error"] == "Invalid credentials."
  end
end