summaryrefslogtreecommitdiff
path: root/lib/pleroma/web/activity_pub/object_validators/listen_validator.ex
blob: 0c5e6819de7241e308cc44a30c2a6d69aeb27c4d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
# Pleroma: A lightweight social networking server
# Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
# SPDX-License-Identifier: AGPL-3.0-only

defmodule Pleroma.Web.ActivityPub.ObjectValidators.ListenValidator do
  use Ecto.Schema

  alias Pleroma.EctoType.ActivityPub.ObjectValidators
  alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations

  import Ecto.Changeset

  @primary_key false
  @derive Jason.Encoder

  embedded_schema do
    quote do
      unquote do
        import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
        message_fields()
      end
    end

    field(:actor, ObjectValidators.ObjectID)
    field(:published, ObjectValidators.DateTime)

    embeds_one :object, UrlObjectValidator, primary_key: false do
      field(:type, :string)

      field(:to, ObjectValidators.Recipients, default: [])
      field(:cc, ObjectValidators.Recipients, default: [])
      field(:bto, ObjectValidators.Recipients, default: [])
      field(:bcc, ObjectValidators.Recipients, default: [])

      field(:title, :string)
      field(:artist, :string)
      field(:album, :string)
      field(:length, :integer)
    end
  end

  def changeset(struct, data) do
    struct
    |> cast(data, __schema__(:fields) -- [:object])
    |> cast_embed(:object, with: &audio_changeset/2)
  end

  def audio_changeset(struct, data) do
    struct
    |> cast(data, Map.keys(struct) -- [:__struct__])
    |> validate_inclusion(:type, ["Audio"])
  end

  def cast_data(data, meta \\ []) do
    data = fix(data, meta)

    %__MODULE__{}
    |> changeset(data)
  end

  def cast_and_validate(data, meta \\ []) do
    data
    |> cast_data(meta)
    |> validate_data(meta)
  end

  defp fix(data, _meta) do
    data
    |> CommonFixes.fix_actor()
    |> CommonFixes.fix_activity_addressing()
  end

  defp validate_data(data_cng, _meta) do
    # TODO: Restrict to Audio objects

    data_cng
    |> validate_inclusion(:type, ["Listen"])
    |> validate_required([:id, :type, :object, :actor, :to, :cc, :published])
    |> CommonValidations.validate_actor_presence()
  end
end