MastodonAPI: /api/v2/media endpoints

3 files changed, 91 insertions, 5 deletions

diff --git a/lib/pleroma/web/mastodon_api/controllers/media_controller.ex b/lib/pleroma/web/mastodon_api/controllers/media_controller.ex
index e36751220..1997ac1af 100644
--- a/lib/pleroma/web/mastodon_api/controllers/media_controller.ex
+++ b/lib/pleroma/web/mastodon_api/controllers/media_controller.ex
@@ -29,6 +29,26 @@ defmodule Pleroma.Web.MastodonAPI.MediaController do
     end
   end
 
+  def create(_conn, _data), do: {:error, :bad_request}
+
+  @doc "POST /api/v2/media"
+  def create2(%{assigns: %{user: user}} = conn, %{"file" => file} = data) do
+    with {:ok, object} <-
+           ActivityPub.upload(
+             file,
+             actor: User.ap_id(user),
+             description: Map.get(data, "description")
+           ) do
+      attachment_data = Map.put(object.data, "id", object.id)
+
+      conn
+      |> put_status(202)
+      |> render("attachment.json", %{attachment: attachment_data})
+    end
+  end
+
+  def create2(_conn, _data), do: {:error, :bad_request}
+
   @doc "PUT /api/v1/media/:id"
   def update(%{assigns: %{user: user}} = conn, %{"id" => id, "description" => description})
       when is_binary(description) do
@@ -42,4 +62,15 @@ defmodule Pleroma.Web.MastodonAPI.MediaController do
   end
 
   def update(_conn, _data), do: {:error, :bad_request}
+
+  @doc "GET /api/v1/media/:id"
+  def show(conn, %{"id" => id}) do
+    with %Object{data: data, id: object_id} <- Object.get_by_id(id) do
+      attachment_data = Map.put(data, "id", object_id)
+
+      render(conn, "attachment.json", %{attachment: attachment_data})
+    end
+  end
+
+  def get_media(_conn, _data), do: {:error, :bad_request}
 end
diff --git a/lib/pleroma/web/router.ex b/lib/pleroma/web/router.ex
index 7a171f9fb..d77a61361 100644
--- a/lib/pleroma/web/router.ex
+++ b/lib/pleroma/web/router.ex
@@ -403,6 +403,7 @@ defmodule Pleroma.Web.Router do
     post("/markers", MarkerController, :upsert)
 
     post("/media", MediaController, :create)
+    get("/media/:id", MediaController, :show)
     put("/media/:id", MediaController, :update)
 
     get("/notifications", NotificationController, :index)
@@ -497,6 +498,8 @@ defmodule Pleroma.Web.Router do
   scope "/api/v2", Pleroma.Web.MastodonAPI do
     pipe_through(:api)
     get("/search", SearchController, :search2)
+
+    post("/media", MediaController, :create2)
   end
 
   scope "/api", Pleroma.Web do
diff --git a/test/web/mastodon_api/controllers/media_controller_test.exs b/test/web/mastodon_api/controllers/media_controller_test.exs
index 6ac4cf63b..d872ff484 100644
--- a/test/web/mastodon_api/controllers/media_controller_test.exs
+++ b/test/web/mastodon_api/controllers/media_controller_test.exs
@@ -11,7 +11,7 @@ defmodule Pleroma.Web.MastodonAPI.MediaControllerTest do
 
   setup do: oauth_access(["write:media"])
 
-  describe "media upload" do
+  describe "Upload media" do
     setup do
       image = %Plug.Upload{
         content_type: "image/jpg",
@@ -25,7 +25,7 @@ defmodule Pleroma.Web.MastodonAPI.MediaControllerTest do
     setup do: clear_config([:media_proxy])
     setup do: clear_config([Pleroma.Upload])
 
-    test "returns uploaded image", %{conn: conn, image: image} do
+    test "/api/v1/media", %{conn: conn, image: image} do
       desc = "Description of the image"
 
       media =
@@ -40,9 +40,31 @@ defmodule Pleroma.Web.MastodonAPI.MediaControllerTest do
       object = Object.get_by_id(media["id"])
       assert object.data["actor"] == User.ap_id(conn.assigns[:user])
     end
+
+    test "/api/v2/media", %{conn: conn, image: image} do
+      desc = "Description of the image"
+
+      response =
+        conn
+        |> post("/api/v2/media", %{"file" => image, "description" => desc})
+        |> json_response(202)
+
+      assert media_id = response["id"]
+
+      media =
+        conn
+        |> get("/api/v1/media/#{media_id}")
+        |> json_response(200)
+
+      assert media["type"] == "image"
+      assert media["description"] == desc
+      assert media["id"]
+      object = Object.get_by_id(media["id"])
+      assert object.data["actor"] == User.ap_id(conn.assigns[:user])
+    end
   end
 
-  describe "PUT /api/v1/media/:id" do
+  describe "Update media description" do
     setup %{user: actor} do
       file = %Plug.Upload{
         content_type: "image/jpg",
@@ -60,7 +82,7 @@ defmodule Pleroma.Web.MastodonAPI.MediaControllerTest do
       [object: object]
     end
 
-    test "updates name of media", %{conn: conn, object: object} do
+    test "/api/v1/media/:id good request", %{conn: conn, object: object} do
       media =
         conn
         |> put("/api/v1/media/#{object.id}", %{"description" => "test-media"})
@@ -70,7 +92,7 @@ defmodule Pleroma.Web.MastodonAPI.MediaControllerTest do
       assert refresh_record(object).data["name"] == "test-media"
     end
 
-    test "returns error when request is bad", %{conn: conn, object: object} do
+    test "/api/v1/media/:id bad request", %{conn: conn, object: object} do
       media =
         conn
         |> put("/api/v1/media/#{object.id}", %{})
@@ -79,4 +101,34 @@ defmodule Pleroma.Web.MastodonAPI.MediaControllerTest do
       assert media == %{"error" => "bad_request"}
     end
   end
+
+  describe "Get media by id" do
+    setup %{user: actor} do
+      file = %Plug.Upload{
+        content_type: "image/jpg",
+        path: Path.absname("test/fixtures/image.jpg"),
+        filename: "an_image.jpg"
+      }
+
+      {:ok, %Object{} = object} =
+        ActivityPub.upload(
+          file,
+          actor: User.ap_id(actor),
+          description: "test-media"
+        )
+
+      [object: object]
+    end
+
+    test "/api/v1/media/:id", %{conn: conn, object: object} do
+      media =
+        conn
+        |> get("/api/v1/media/#{object.id}")
+        |> json_response(:ok)
+
+      assert media["description"] == "test-media"
+      assert media["type"] == "image"
+      assert media["id"]
+    end
+  end
 end